login!

src/switcheroo.gleam

@@ -1,5 +1,23 @@
-import gleam/io
+import envoy
+import gleam/erlang/process
+import gleam/int
+import mist
+import switcheroo/router
+import wisp
+import wisp/wisp_mist
 
 pub fn main() -> Nil {
-  io.println("Hello from switcheroo!")
+  wisp.configure_logger()
+
+  let assert Ok(secret_key_base) = envoy.get("SECRET_KEY")
+  let assert Ok(port_str) = envoy.get("PORT")
+  let assert Ok(port) = int.parse(port_str)
+
+  let assert Ok(_) =
+    wisp_mist.handler(router.handle_request, secret_key_base)
+    |> mist.new
+    |> mist.port(port)
+    |> mist.start_http
+
+  process.sleep_forever()
 }

src/switcheroo/login.gleam

@@ -0,0 +1,54 @@
+import gleam/http.{Delete, Get, Post}
+import gleam/list
+import gleam/string_tree
+import wisp.{type Request, type Response}
+
+pub const cookie_name = "pluralkit_token"
+
+pub fn login(req: Request) -> Response {
+  case req.method {
+    Get -> get_login(req)
+    Post -> post_login(req)
+    Delete -> delete_login(req)
+    _ -> wisp.method_not_allowed([Get, Post, Delete])
+  }
+}
+
+fn get_login(_req: Request) -> Response {
+  [
+    "<p>Hi, need that one's PluralKit token! <3</p>",
+    "<form action='/login' method='post'>",
+    "  <label for='token'><b>PluralKit Token</b></label>",
+    "  <input type='string' name='token' id='token' />",
+    "  <input type='submit' value='Login'/>", "</form>",
+  ]
+  |> string_tree.from_strings
+  |> wisp.html_response(200)
+}
+
+fn post_login(req: Request) -> Response {
+  use formdata <- wisp.require_form(req)
+
+  let resp = wisp.redirect("/")
+  case list.key_find(formdata.values, "token") {
+    Ok(token) ->
+      wisp.set_cookie(
+        resp,
+        req,
+        cookie_name,
+        token,
+        wisp.Signed,
+        60 * 60 * 24 * 365,
+      )
+    Error(_) ->
+      wisp.set_header(resp, "x-servfail", "token not found in formdata")
+  }
+}
+
+fn delete_login(req: Request) -> Response {
+  let resp = wisp.redirect("/session")
+  case wisp.get_cookie(req, cookie_name, wisp.Signed) {
+    Ok(value) -> wisp.set_cookie(resp, req, cookie_name, value, wisp.Signed, 0)
+    Error(_) -> resp
+  }
+}

src/switcheroo/picker.gleam

@@ -0,0 +1,7 @@
+import gleam/string_tree
+import wisp.{type Request, type Response}
+
+pub fn picker(_req: Request) -> Response {
+  string_tree.from_string("<h1>test</h1>")
+  |> wisp.html_response(200)
+}

src/switcheroo/router.gleam

@@ -0,0 +1,31 @@
+import gleam/http.{Get}
+import switcheroo/login
+import switcheroo/picker
+import switcheroo/web
+import wisp.{type Request, type Response}
+
+pub fn handle_request(req: Request) -> Response {
+  use req <- web.middleware(req)
+
+  case wisp.path_segments(req) {
+    [] -> home_page(req)
+
+    ["login"] -> login.login(req)
+    ["picker"] -> picker.picker(req)
+
+    _ -> wisp.not_found()
+  }
+}
+
+fn home_page(req: Request) -> Response {
+  use <- wisp.require_method(req, Get)
+
+  case wisp.get_cookie(req, login.cookie_name, wisp.Signed) {
+    Ok(_) -> {
+      wisp.redirect("/picker")
+    }
+    Error(_) -> {
+      wisp.redirect("/login")
+    }
+  }
+}

src/switcheroo/web.gleam

@@ -0,0 +1,12 @@
+import wisp
+
+pub fn middleware(
+  req: wisp.Request,
+  handle_request: fn(wisp.Request) -> wisp.Response,
+) -> wisp.Response {
+  let req = wisp.method_override(req)
+  use <- wisp.log_request(req)
+  use <- wisp.rescue_crashes
+  use req <- wisp.handle_head(req)
+  handle_request(req)
+}